packages/flake.nix

{
  description = "meterriblecrew.net package flake";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-20.09-small";

  outputs = inputs@{ self, nixpkgs }: let

    systems = [
      "x86_64-linux"
      "i686-linux"
      "x86_64-darwin"
      "aarch64-linux"
      "armv6l-linux"
      "armv7l-linux"
    ];
    forAllSystems = f: nixpkgs.lib.genAttrs systems (system: f system);

  in {

    nixosModules = {
      ryzenSMU = import ./modules/ryzenSMU;

      servicesSnipeIT = import ./modules/services/snipe-it.nix;
    };

    packages = forAllSystems (system: import ./. {
      pkgs = import nixpkgs { inherit system; };
    });

    overlay = next: prev: 
      let localPkgs = import ./. { pkgs = next; };
      in {
        inherit (localPkgs)
          janus-gateway
          nextcloud-spreed-signaling
          usrsctp
          ;
      } // prev.lib.optionalAttrs (prev.system == "x86_64-linux") {
        inherit (localPkgs)
          ryzenadj
          ryzen_smu
          ;
      };

  };

}