vivaldi: init at 4.1.2369.21-1

This is in nixpkgs-unstable and PR'ed for 21.05 (#134496) but doesn't
make progress so far, thus init here.  Expression is basically copied
from nixpkgs-unstable.
master
Andreas Wiese 2021-09-09 00:14:32 +02:00
parent 995affe9dc
commit 324294e8a8
3 changed files with 109 additions and 3 deletions

View File

@ -12,7 +12,7 @@ in rec {
snipe-it = callPackage ./pkgs/snipe-it { };
} // optionalAttrs (pkgs.system == "x86_64-linux") {
} // optionalAttrs (pkgs.system == "x86_64-linux") rec {
chrysalis-bin = callPackage ./pkgs/chrysalis-bin { };
@ -22,4 +22,6 @@ in rec {
ryzen_smu = callPackage ./pkgs/ryzen_smu { kernel = pkgs.linux; };
vivaldi = callPackage ./pkgs/vivaldi { };
}

View File

@ -25,7 +25,7 @@
};
packages = forAllSystems (system: import ./. {
pkgs = import nixpkgs { inherit system; };
pkgs = import nixpkgs { inherit system; config = { allowUnfree = true; }; };
});
overlay = next: prev:
@ -36,12 +36,13 @@
nextcloud-spreed-signaling
snipe-it
;
} // prev.lib.optionalAttrs (prev.system == "x86_64-linux") {
} // prev.lib.optionalAttrs (prev.system == "x86_64-linux") rec {
inherit (localPkgs)
chrysalis-bin
navidrome-bin
ryzenadj
ryzen_smu
vivaldi
;
};

103
pkgs/vivaldi/default.nix Normal file
View File

@ -0,0 +1,103 @@
{ lib, stdenv, fetchurl, zlib, libX11, libXext, libSM, libICE, libxkbcommon, libxshmfence
, libXfixes, libXt, libXi, libXcursor, libXScrnSaver, libXcomposite, libXdamage, libXtst, libXrandr
, alsaLib, dbus, cups, libexif, ffmpeg, systemd
, freetype, fontconfig, libXft, libXrender, libxcb, expat
, libuuid
, libxml2
, glib, gtk3, pango, gdk-pixbuf, cairo, atk, at-spi2-atk, at-spi2-core, gnome2
, libdrm, mesa
, nss, nspr
, patchelf, makeWrapper
, isSnapshot ? false
, proprietaryCodecs ? false, vivaldi-ffmpeg-codecs ? null
, enableWidevine ? false, vivaldi-widevine ? null
}:
let
branch = if isSnapshot then "snapshot" else "stable";
vivaldiName = if isSnapshot then "vivaldi-snapshot" else "vivaldi";
in stdenv.mkDerivation rec {
pname = "vivaldi";
version = "4.1.2369.21-1";
src = fetchurl {
url = "https://downloads.vivaldi.com/${branch}/vivaldi-${branch}_${version}_amd64.deb";
sha256 = "03062mik6paqp219jz420jsg762jjrfxmj1daq129z2zgzq0qr8l";
};
unpackPhase = ''
ar vx $src
tar -xvf data.tar.xz
'';
nativeBuildInputs = [ patchelf makeWrapper ];
buildInputs = [
stdenv.cc.cc stdenv.cc.libc zlib libX11 libXt libXext libSM libICE libxcb libxkbcommon libxshmfence
libXi libXft libXcursor libXfixes libXScrnSaver libXcomposite libXdamage libXtst libXrandr
atk at-spi2-atk at-spi2-core alsaLib dbus cups gtk3 gdk-pixbuf libexif ffmpeg systemd
freetype fontconfig libXrender libuuid expat glib nss nspr
libxml2 pango cairo gnome2.GConf
libdrm mesa
] ++ lib.optional proprietaryCodecs vivaldi-ffmpeg-codecs;
libPath = lib.makeLibraryPath buildInputs
+ lib.optionalString (stdenv.is64bit)
(":" + lib.makeSearchPathOutput "lib" "lib64" buildInputs)
+ ":$out/opt/${vivaldiName}/lib";
buildPhase = ''
runHook preBuild
echo "Patching Vivaldi binaries"
for f in crashpad_handler vivaldi-bin vivaldi-sandbox ; do
patchelf \
--set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" \
--set-rpath "${libPath}" \
opt/${vivaldiName}/$f
done
'' + lib.optionalString proprietaryCodecs ''
ln -s ${vivaldi-ffmpeg-codecs}/lib/libffmpeg.so opt/${vivaldiName}/libffmpeg.so.''${version%\.*\.*}
'' + ''
echo "Finished patching Vivaldi binaries"
runHook postBuild
'';
dontPatchELF = true;
dontStrip = true;
installPhase = ''
runHook preInstall
mkdir -p "$out"
cp -r opt "$out"
mkdir "$out/bin"
ln -s "$out/opt/${vivaldiName}/${vivaldiName}" "$out/bin/vivaldi"
mkdir -p "$out/share"
cp -r usr/share/{applications,xfce4} "$out"/share
substituteInPlace "$out"/share/applications/*.desktop \
--replace /usr/bin/${vivaldiName} "$out"/bin/vivaldi
substituteInPlace "$out"/share/applications/*.desktop \
--replace vivaldi-stable vivaldi
local d
for d in 16 22 24 32 48 64 128 256; do
mkdir -p "$out"/share/icons/hicolor/''${d}x''${d}/apps
ln -s \
"$out"/opt/${vivaldiName}/product_logo_''${d}.png \
"$out"/share/icons/hicolor/''${d}x''${d}/apps/vivaldi.png
done
wrapProgram "$out/bin/vivaldi" \
--suffix XDG_DATA_DIRS : ${gtk3}/share/gsettings-schemas/${gtk3.name}/ \
${lib.optionalString enableWidevine "--suffix LD_LIBRARY_PATH : ${libPath}"}
'' + lib.optionalString enableWidevine ''
ln -sf ${vivaldi-widevine}/share/google/chrome/WidevineCdm $out/opt/${vivaldiName}/WidevineCdm
'' + ''
runHook postInstall
'';
meta = with lib; {
description = "A Browser for our Friends, powerful and personal";
homepage = "https://vivaldi.com";
license = licenses.unfree;
maintainers = with maintainers; [ otwieracz badmutex ];
platforms = [ "x86_64-linux" ];
};
}